BÀI 3. VẼ ĐỒ THỊ VÀ CÁC VẤN ĐỀ LIÊN QUAN
1. Khởi tạo các hàm vẽ đồ thị
> with(plots):
Warning, the previous binding of the name arrow has been removed and it now has an assigned value
> with(plottools):
2. Vẽ đồ thị trong không gian 2 chiều Oxy
Vẽ đồ thị hàm thông thường:
Cú pháp: plot(ham_can_ve, x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi, cac_tuy_chon);
Một số tùy chọn thông dụng:
- Đặt màu cho đồ thị: color = <màu>
- Đặt độ dày k cho đồ thị: thickness = k
- Đặt số điểm vẽ cho đồ thị: numpoints = k;
> plot(x^3-3*x^2+1,x=-5..5,y=-5..5):
> f:=x->abs(x^3-x^2-2*x)/3-abs(x+1):
> plot(f(x),x=-5..5,y=-5..5):
Vẽ nhiều đồ thị trên cùng một hệ trục
Cú pháp: plot([ham_1, ham_2,...], x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi, cac_tuy_chon);
> plot([x^2,sin(x)],x=-2..2,color=[red,green]):
Vẽ đồ thị của hàm số không liên tục
Khi vẽ đồ thị của một hoặc nhiều hàm số có điểm gián đoạn, ta phải thêm tuy chọn discont =
true để đồ thị được vẽ chính xác hơn
> g:=x->(x^2-1)/(x-2):
> plot(g(x),x=-10..10,y=-5..15,discont=true,color=blue):
Vẽ đồ thị hàm ẩn
Có những hàm số mà chúng ta không có được công thức tường minh y=f(x), khi đó để vẽ được đồ
thị của chúng, ta sẽ dùng hàm implicitplot
Cú pháp: implicitplot([bt_1, bt_2,...], x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi, cac_tuy_chon);
> implicitplot(x^2/9+y^2/4=1,x=-4..4,y=-2..2):
> implicitplot(x^2-y^2-x^4=0,x=-1..1,y=-1..1):
Ứng dụng: vẽ đồ thị của hàm hữu tỷ
> f:=x->(x^2-1)/(x-2):
> bt:=convert(f(x),parfrac):
> tcx:=x->x+2:
> g1:=plot([f(x),tcx(x)],x=-10..10,y=-5..15,color=[blue,red],discont=true):
> g2:=implicitplot(x=2,x=-10..10,y=-5..15,color=green):
> display({g1,g2}):
3. Vẽ đồ thị trong không gian 3 chiều Oxyz
Vẽ đồ thị hàm thông thường
Cú pháp: plot3d(ham_can_ve, x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi,z=gt_dau..gt_cuoi, cac_tuy_chon);
> plot3d(x*exp(x^2),x=-2..2,y=-2..2,title="Do thi trong khong gian 3 chieu"):
> plot3d(-exp(-abs(x*y)/10)*sin(x+y)-cos(x*y),x=-Pi..Pi,y=-Pi..Pi,grid=[51,51]):
Vẽ đồ thị hàm ẩn
Cú pháp: implicitplot3d(ham_can_ve, x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi,z=gt_dau..gt_cuoi, cac_tuy_chon);
> implicitplot3d(x^2+y^2/4+z^2/9=1,x=-3..3,y=-3..3,z=-3..3):
4. Sự vận động của đồ thị
Cú pháp: animate(ham_co_tham_so,x=gt_dau..gt_cuoi, tham_so = gt_dau..gt_cuoi);
animate3d(ham_co_tham_so,x=gt_dau..gt_cuoi, y=gt_dau..gt_cuoi, tham_so =
gt_dau..gt_cuoi);
Ý nghĩa: hiển thị sự biến đổi, vận động của đồ thị khi tham số thay đổi trong khoảng cho trước
> animate3d(cos(t*x)*sin(t*y),x=-Pi..Pi,y=-Pi..Pi,t=1..5):
> animate(t*x^2,x=-3..3,t=-5..5):
Download |
Không có nhận xét nào:
Đăng nhận xét